Exporting index for external USB drive or storing/external drive index on external drive

[EchterStahlmann]

Hello,

I have external USB drive. I want to have there Everything software with its database WITH ONLY content of USB HDD (because beforementioned USB HDD is used on MANY different PCs). I also DON'T want to collect data from new computers.

The letter of USB drive will change constantly :/

I downloaded portable version and put it on USB HDD.

What should I do next?


Cheers

[EchterStahlmann]

Ok, I see that there is .db file on external drive. Is everything correct now?

[NotNull]

- Put Everything.exe somewhere on your external disk
- In the same folder, create Everything.ini with this content:

Code: Select all

; Please make sure Everything is not running before modifying this file.
[Everything]
run_as_admin=0
run_in_background=0
show_in_taskbar=1
show_tray_icon=0
minimize_to_tray=0
check_for_updates_on_startup=0
instance_name=TEST
auto_include_fixed_volumes=0
auto_include_removable_volumes=0
auto_include_fixed_refs_volumes=0
auto_include_removable_refs_volumes=0
folders="\\"

- Change "TEST" in instance_name=TEST to something unique, like PROJECT-DISK (to avoid mixing up with other running instances of Everything)
- Start Everything.exe from your external disk
- Configure other Everything settings - like Window title bar and rescan interval - to your liking.
- Exit Everything to write database and changed INI to external disk.


Because of folders="\\" instead of "X:\\" it will change the disk to the current mapping (i.e. driveletter changes to Y:).

[Stamimail]

Because of folders="\\" instead of "X:\\" it will change the disk to the current mapping (i.e. driveletter changes to Y:).

Doesn't it mean it will perform Folder indexing rathrer than NTFS indexing?

[NotNull]

Because of folders="\\" instead of "X:\\" it will change the disk to the current mapping (i.e. driveletter changes to Y:).

Doesn't it mean it will perform Folder indexing rathrer than NTFS indexing?

Good point! Yes, it does. I chose for Folder indexing because @EchterStahlmann wrote:
".. beforementioned USB HDD is used on MANY different PCs ..."

Folder indexing works even if people are not admin on those systems.

[Stamimail]

Folder indexing works even if people are not admin on those systems.

Is there a way to perform NTFS indexing just for the portable storage, in the case the user has admin privileges, like PCs at home.

[NotNull]

Folder indexing works even if people are not admin on those systems.

Is there a way to perform NTFS indexing just for the portable storage, in the case the user has admin privileges, like PCs at home.

I did some experiments with that a couple of months ago. Turned out it was possible, using a CMD script to start Everything on this portable disk. But I deleted it (challenge completed and I don't need it).
If you're interested, I can do it again (and post it this time )

[Stamimail]

I don't need it now, but when me/someone needs it, he would be glad to find it here...

[NotNull]

I don't need it now, but when me/someone needs it, he would be glad to find it here...

Here you go ..

[*] Put Everything.exe somewhere on your external disk
[*] Save next code as (for example) INSTALL.cmd in the same folder

Code: Select all

@echo off
setlocal
pushd "%~dp0"

::__________________[ Basic settings ]__________________________
(
    echo [Everything]

    echo run_as_admin=1

    echo allow_http_server=0
    echo allow_etp_server=0

    echo run_in_background=0
    echo show_in_taskbar=1
    echo show_tray_icon=0
    echo minimize_to_tray=0
    echo hide_on_close=0

    echo check_for_updates_on_startup=0

    echo run_history_enabled=0

    echo auto_include_fixed_volumes=0
    echo auto_include_removable_volumes=0
    echo auto_remove_offline_ntfs_volumes=0
    echo auto_remove_moved_ntfs_volumes=1
    echo auto_include_fixed_refs_volumes=1
    echo auto_include_removable_refs_volumes=0
    echo find_mount_points_on_removable_volumes=0
    echo ntfs_volume_includes=1
    echo ntfs_volume_load_recent_changes=1
    echo ntfs_volume_include_onlys="",""
    echo ntfs_volume_monitors=1
    echo ntfs_volume_roots="\\\\"

) > Everything.ini
::===========================================================



::__________________[ Device ID ]__________________________

    for /f "usebackq delims=" %%x in (`wmic volume WHERE "DriveLetter='%~d0'" get DeviceID /FORMAT:value`) Do set %%x>nul
    set DeviceID=%DeviceID:\=\\%
    echo ntfs_volume_guids="%DeviceID%">> Everything.ini
::===========================================================


::__________________[ Instance Name ]__________________________

    for /f "usebackq delims=" %%x in (`wmic volume WHERE "DriveLetter='%~d0'" get Label /FORMAT:value`) Do set %%x>nul
    echo instance_name=%Label%>> Everything.ini
::===========================================================

[*] Run this script.
[*] You don't need this script any longer on this disk; you can remove if you want.


[*] Save next code as (for example) RUN.cmd in the same folder

Code: Select all

@setlocal
pushd "%~dp0"
echo ntfs_volume_paths="%~d0">> Everything.ini
start "" Everything.exe

[*] Every time you want to start Everything, use this RUN.cmd script instead of Everything.exe


Remarks

[*] The instance name is based on the volume label of the disk. If your disk hasn't got a volume label (yet):
- create one (right-click on the disk in Explorer and choose "Rename") and run INSTALL.cmd again OR
- Manually change the instance_name= entry in Everything.ini

[*] Don't think this is the same as the one I did before, but this seems to work too